SCL DB 备份与恢复：WRIT_DBL / READ_DBL 序列

1FUNCTION_BLOCK "FB_BlockBackup"
2{ S7_Optimized_Access := 'TRUE' }
3VERSION : 0.1
4   VAR_INPUT
5      Nr : Int;   // 当前块号（1..LastBlock）
6   END_VAR
7 
8   VAR_IN_OUT
9      MainHeader : Struct
10         Save : Bool;        // TRUE = 启动备份
11         Restore : Bool;     // TRUE = 启动恢复
12         WrCounter : Int;    // 已完成的写块数
13         RdCounter : Int;    // 已完成的读块数
14         LastBlock : Int;    // 最后一块的编号
15      END_STRUCT;
16      BlockHeader : Struct
17         Save : Bool;
18         Restore : Bool;
19         Write : Bool;
20         WrBusy : Bool;
21         WrProcess : Bool;
22         WrDone : Bool;
23         WrRet : Int;
24         WrRetMem : Int;
25         Read : Bool;
26         RdBusy : Bool;
27         RdProcess : Bool;
28         RdDone : Bool;
29         RdRet : Int;
30         RdRetMem : Int;
31      END_STRUCT;
32      DBBlock : Variant;   // 要备份/恢复的 DB
33   END_VAR
34 
35BEGIN
36   REGION 备份
37      // 只有当前块号等于写计数器时，才轮到这一块。
38      IF #MainHeader.Save AND NOT #MainHeader.Restore AND #MainHeader.WrCounter = #Nr AND NOT #BlockHeader.Save THEN
39         #BlockHeader.Save := TRUE;
40      END_IF;
41      // 恢复优先：恢复请求有效时，撤销本块的备份请求。
42      IF #MainHeader.Restore THEN
43         #BlockHeader.Save := FALSE;
44         #MainHeader.Save := FALSE;
45      END_IF;
46      IF #MainHeader.WrCounter = 0 THEN
47         #MainHeader.WrCounter := 1;
48      END_IF;
49 
50      // 启动一次写：WrProcess 防止重复触发，Write 只给一个周期。
51      IF #BlockHeader.Save AND NOT #BlockHeader.WrProcess THEN
52         #BlockHeader.WrProcess := TRUE;
53         #BlockHeader.Write := TRUE;
54         #BlockHeader.WrDone := FALSE;
55      END_IF;
56 
57      IF #BlockHeader.Save THEN
58         #BlockHeader.WrRet := WRIT_DBL(
59            REQ := #BlockHeader.Write,
60            SRCBLK := #DBBlock,
61            BUSY => #BlockHeader.WrBusy,
62            DSTBLK := #DBBlock);
63      END_IF;
64 
65      IF #BlockHeader.WrBusy THEN
66         #BlockHeader.Write := FALSE;
67         #BlockHeader.WrRetMem := #BlockHeader.WrRet;
68      END_IF;
69 
70      // RET_VAL 0 和 28672（后台完成）都算成功。
71      IF #BlockHeader.WrProcess AND ((#BlockHeader.WrRet = 0) OR (#BlockHeader.WrRet = 28672)) THEN
72         #MainHeader.WrCounter := #MainHeader.WrCounter + 1;
73         #BlockHeader.WrProcess := FALSE;
74         #BlockHeader.Save := FALSE;
75         #BlockHeader.WrDone := TRUE;
76      END_IF;
77 
78      IF #MainHeader.WrCounter = #MainHeader.LastBlock + 1 THEN
79         #MainHeader.WrCounter := 0;
80         #MainHeader.Save := FALSE;
81      END_IF;
82   END_REGION
83 
84   REGION 恢复
85      IF #MainHeader.RdCounter = 0 THEN
86         #MainHeader.RdCounter := 1;
87      END_IF;
88      IF #MainHeader.Restore AND #MainHeader.RdCounter = #Nr AND NOT #BlockHeader.Restore AND NOT #BlockHeader.WrProcess THEN
89         #BlockHeader.Restore := TRUE;
90      END_IF;
91 
92      IF #BlockHeader.Restore AND NOT #BlockHeader.RdProcess THEN
93         #BlockHeader.RdProcess := TRUE;
94         #BlockHeader.Read := TRUE;
95         #BlockHeader.RdDone := FALSE;
96      END_IF;
97 
98      IF #BlockHeader.Restore THEN
99         #BlockHeader.RdRet := READ_DBL(
100            REQ := #BlockHeader.Read,
101            SRCBLK := #DBBlock,
102            BUSY => #BlockHeader.RdBusy,
103            DSTBLK := #DBBlock);
104      END_IF;
105 
106      IF #BlockHeader.RdBusy THEN
107         #BlockHeader.Read := FALSE;
108         #BlockHeader.RdRetMem := #BlockHeader.RdRet;
109      END_IF;
110 
111      IF #BlockHeader.RdProcess AND ((#BlockHeader.RdRet = 0) OR (#BlockHeader.RdRet = 28672)) THEN
112         #MainHeader.RdCounter := #MainHeader.RdCounter + 1;
113         #BlockHeader.RdProcess := FALSE;
114         #BlockHeader.Restore := FALSE;
115         #BlockHeader.RdDone := TRUE;
116      END_IF;
117 
118      IF #MainHeader.RdCounter = #MainHeader.LastBlock + 1 THEN
119         #MainHeader.RdCounter := 1;
120         #MainHeader.Restore := FALSE;
121      END_IF;
122   END_REGION
123END_FUNCTION_BLOCK
124 

1DATA_BLOCK "DB_BackupControl"
2{ S7_Optimized_Access := 'TRUE' }
3VERSION : 0.1
4   VAR
5      MainHeader : Struct
6         Save : Bool;
7         Restore : Bool;
8         WrCounter : Int;
9         RdCounter : Int;
10         LastBlock : Int;
11      END_STRUCT;
12      Blocks : Array[1..4] of Struct
13         Save : Bool;
14         Restore : Bool;
15         Write : Bool;
16         WrBusy : Bool;
17         WrProcess : Bool;
18         WrDone : Bool;
19         WrRet : Int;
20         WrRetMem : Int;
21         Read : Bool;
22         RdBusy : Bool;
23         RdProcess : Bool;
24         RdDone : Bool;
25         RdRet : Int;
26         RdRetMem : Int;
27      END_STRUCT;
28   END_VAR
29BEGIN
30   MainHeader.LastBlock := 4;
31END_DATA_BLOCK
32